package ro.badu.utils.debug
{
	import flash.utils.getQualifiedClassName;
	import flash.utils.getTimer;
 
	import mx.utils.ObjectUtil;
 
	CONFIG::AIR_LOG
	{
		import ro.badu.utils.debug.logger.LogWriter;
	}
	/*
		A simple class which allows you to perform "extensive" traces.
 
		@authors :
			Per Kristian Stoveland - perk.stoveland[at]gmail.com (original)
			Dinu Bogdan Gabriel - badu[at]badu.ro
 
		Usage example:
 
		protected function someMethod():void
		{
 
			var myArrayCollection : ArrayCollection = new ArrayCollection();
			myArrayCollection.addItem({firstname:"test1" , lastname: "test2"});
			myArrayCollection.addItem({firstname:"test3" , lastname: "test4"});
 
			OldTracer.log( this , "someMethod" , myArrayCollection , true);
 
		}
 
		public static function log( inClass:Object, inMethod:String = "", message:Object=null, isObjectUtilDump : Boolean = false ):void
 
		Parameters : 
			inClass - where is the place the trace comes from 
			inMethod - usually a string that you have to complete by hand to illustrate in which method
			message - the message you want to trace. Can accept complex objects which in combination with isObjectUtilDump= true will
				use ObjectUtil to dump it all
			isObjectUtilDump - see above
 
		Note : do not forget to set compiler params -define CONFIG::DEBUG true -define CONFIG::AIR_LOG false if you are using it as it is
	*/
	public class OldTracer 
	{
 
		private static var _useQName:Boolean = true;
 
		public static function set useQualifiedClassName( b:Boolean):void
		{
			_useQName = b;
		} 
 
		public static function log( inClass:Object, inMethod:String = "", message:Object=null, isObjectUtilDump : Boolean = false ):void 
		{
			if (CONFIG::AIR_LOG)
			{
				var _log:LogWriter = new LogWriter();
			}
			try 
			{
				var className:String = getQualifiedClassName( inClass );
 
				if( !_useQName )
				{
					var start:uint = className.indexOf( "::" ) + 2;
					className = className.substring( start, className.length );
				}
			} 
			catch( e:Error ) 
			{
				trace( "Can not get qualified class name for: " + inClass.toString() + " in Tracer." );
				return;
			}
			var _tracedMessage:String ;
 
			_tracedMessage = "[" + getTimer() + "]\t" + className;
 
			if( inMethod == "" ) _tracedMessage += "()";			
			else _tracedMessage += "/" + inMethod + "()";
 
			if (isObjectUtilDump)
			{
				if( message != null ) _tracedMessage += "\n" + ObjectUtil.toString(message);
			}
			else
			{
				if( message != null ) _tracedMessage += " - " + message;	
			}			
 
			if (CONFIG::AIR_LOG)
			{
				_log.log(_tracedMessage);
			}
 
			trace(_tracedMessage); 
		}
 
	}
}

package ro.badu.utils.debug
{
	import flash.utils.getTimer;
 
	import mx.utils.ObjectUtil;
 
	CONFIG::AIR_LOG
	{
		import ro.badu.utils.debug.logger.LogWriter;
	}
	/*
	A simple class which allows you to perform extensive traces with line numbers.
 
	@author :
	Dinu Bogdan Gabriel - badu[at]badu.ro
 
	Usage example:
 
	protected function someMethod():void
	{
 
		var myArrayCollection : ArrayCollection = new ArrayCollection();
		myArrayCollection.addItem({firstname:"test1" , lastname: "test2"});
		myArrayCollection.addItem({firstname:"test3" , lastname: "test4"});
 
		Tracer.log( new Error() , myArrayCollection , true);
	}
 
	public static function log( source : Error , message:Object=null,  isObjectUtilDump : Boolean = false ):void
 
	Parameters :
	source : Error - the place where the trace comes from, usually using "new Error()" will provide all the info you need, regardless of the
							type of class / method
	message - the message you want to trace. Can accept complex objects which in combination with isObjectUtilDump= true will
							use ObjectUtil to dump it all
	isObjectUtilDump - see above
 
	Important Note : 
 
		1. do not forget to set compiler param -define CONFIG::AIR_LOG false if you are using it as it is
		2. I recommend you to use -define CONFIG::DEBUG true too and do conditionals on traces that are "permanent" (remains there until you deliver)
 
	*/
	public class Tracer
	{
 
		public static const brackets : RegExp = new RegExp(/\[|\]/ig);
		public static const linebreak : RegExp = new RegExp(/\n/ig);
		public static const twopoints : RegExp = new RegExp(/\:/ig);
		public static const doubletwopoints : RegExp = new RegExp(/\::/ig);
 
		public static function log( source : Error , message:Object=null,  isObjectUtilDump : Boolean = false ):void
		{
			if (CONFIG::AIR_LOG)
			{
				var _log:LogWriter = new LogWriter();
			}
 
			var _tracedMessage:String ;
			var _lines : Array = (source.getStackTrace().split(linebreak)[1] as String).split(brackets);
			var _where : String = _lines[0] as String;
			var _sourceFile : String = (_lines[1] as String).split(twopoints)[2] as String;
			_where = _where.replace(doubletwopoints , " => ");
			_tracedMessage = "[" + getTimer() + " ms]" + _where.replace(".." , "\t")+"  [LINE #"+_sourceFile+"]";
 
			if (isObjectUtilDump)
			{
				if( message != null ) _tracedMessage += "\n" + ObjectUtil.toString(message);
			}
			else
			{
				if( message != null ) _tracedMessage += " - " + message;
			}		
 
			if (CONFIG::AIR_LOG)
			{
				_log.log(_tracedMessage);
			}
 
			trace(_tracedMessage);
		}
 
	}
}